tofu-modules-aws-doppler/main.tf at main · codeforamerica/tofu-modules-aws-doppler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
resource "aws_iam_policy" "this" {
  name        = local.name
  description = "Policy to allow Doppler to access secrets in AWS Secrets Manager."

  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Sid    = "AllowSecretsAccess"
        Effect = "Allow"
        Action = [
          "secretsmanager:GetSecretValue",
          "secretsmanager:DescribeSecret",
          "secretsmanager:PutSecretValue",
          "secretsmanager:CreateSecret",
          "secretsmanager:DeleteSecret",
          "secretsmanager:TagResource",
          "secretsmanager:UpdateSecret"
        ]
        Resource = "*"
      },
      {
        Sid    = "AllowKMSAccess"
        Effect = "Allow"
        Action = [
          "kms:DescribeKey",
          "kms:ListAliases",
          "kms:ListKeys",
          "kms:Encrypt",
          "kms:Decrypt",
          "kms:ReEncrypt*",
          "kms:GenerateDataKey*"
        ]
        Resource = var.kms_key_arns
      },
    ]
  })

  tags = var.tags
}

resource "aws_iam_role" "this" {
  name = local.name

  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Action = "sts:AssumeRole"
        Principal = {
          AWS = "arn:aws:iam::${var.doppler_aws_account_id}:root"
        },
        Condition = {
          StringEquals = {
            "sts:ExternalId" = var.doppler_workspace_id
          }
        }
      },
    ]
  })

  tags = var.tags
}

resource "aws_iam_role_policy_attachments_exclusive" "this" {
  role_name   = aws_iam_role.this.name
  policy_arns = [aws_iam_policy.this.arn]
}

module "sync" {
  source = "./modules/sync"

  for_each = var.create_sync ? toset(["this"]) : toset([])

  doppler_project  = var.doppler_project
  environment      = var.environment
  environment_slug = var.doppler_environment_slug
  iam_role_arn     = aws_iam_role.this.arn
  program          = var.program
  project          = var.project
  region           = data.aws_region.current.region
  service          = var.service
}