justfile

alias b := build
alias c := check
alias f := fmt
alias m := msrv
alias p := pre-push
alias t := test

_default:
   @just --list

# Build the project
build:
   cargo build

# Check code formatting, compilation, linting, documentation and commit signature
check:
   cargo +nightly fmt --all -- --check
   cargo check --all-features --all-targets
   cargo clippy --all-features --all-targets -- -D warnings
   RUSTDOCFLAGS="-D warnings" cargo doc --all-features --no-deps
   @[ "$(git log --pretty='format:%G?' -1 HEAD)" = "N" ] && \
       echo "\n⚠️  Unsigned commit: BDK requires that commits be signed." || \
       true

# Format all code
fmt:
   cargo +nightly fmt

# Build and test using the MSRV toolchain (1.75.0)
msrv:
   rm -rf Cargo.lock
   bash ci/pin-msrv.sh
   cargo +1.75.0 build --all-features
   cargo +1.75.0 test --all-features -- --test-threads=16

# Run pre-push suite: format, check, and test
pre-push: fmt check test msrv

# Run all tests on the workspace with all features
test:
   cargo test --all-features -- --test-threads=16